{
  config,
  pkgs,
  lib,
  osConfig,
  ...
}:
let
  inherit (config.my) font theme;
  monolithAutostart = lib.optionalString ((osConfig.networking.hostName or "") == "monolith") ''
    spawn-at-startup "steam"
    spawn-at-startup "obs" "--startreplaybuffer" "--disable-shutdown-check"
    spawn-at-startup "deluge-gtk"
    spawn-at-startup "nicotine"
  '';
in
{
  imports = [
    ../sway/kanshi.nix
    ../sway/mako.nix
    ../sway/swayidle.nix
    ../sway/swaylock.nix
    ../sway/gammastep.nix
    ./theme.nix
  ];

  config = lib.mkIf (config.my.niri.enable or false) {
    my.mako.enable = true;
    my.kanshi.enable = true;
    my.swayidle.enable = true;
    my.swaylock.enable = true;
    my.mpd.enable = true;
    my.zathura.enable = true;
    my.satty.enable = true;
    my.waybar.enable = true;
    my.gammastep.enable = true;

    xdg.configFile."niri/config.kdl".text = ''
      ${builtins.readFile ./config.kdl}
      ${monolithAutostart}
    '';

    services.kdeconnect = {
      enable = true;
      indicator = true;
    };

    services.gpg-agent.pinentry.package = pkgs.pinentry-all;

    xdg.configFile."OpenTabletDriver/settings.json" = {
      force = true;
      source = ../sway/open-tablet-driver.json;
    };

    home.packages = with pkgs; [
      swaybg
      swaylock
      wdisplays

      dhist
      demoji
      bmenu
      wdmenu
      wlauncher
      volumesh
      brightnessctl
      showkeys
      pamixer
      libnotify
      xdg-utils
      screenshotsh
      color_picker
      wf-recorder
      wl-clipboard
      wtype
      wl-crosshair
      caffeinated

      grim
      satty
      xdg-user-dirs
      (tesseract5.override {
        enableLanguages = [
          "eng"
          "por"
        ];
      })
    ];
  };
}