sway: use caffeinated instead of disabling swayidle

pkgs/caffeinated/default.nix

@@ -0,0 +1,51 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+
+  pkgconf,
+  pkg-config,
+  wayland-scanner,
+
+  systemd,
+  libbsd,
+  wayland,
+  wayland-protocols,
+}:
+
+stdenv.mkDerivation {
+  pname = "caffeinated";
+  version = "2022-12-08";
+
+  src = fetchFromGitHub {
+    owner = "electrickite";
+    repo = "caffeinated";
+    rev = "5a8eff054bdce225a19cf3ab785dc1bbc9bd3265";
+    hash = "sha256-X1w/YWljcwb5ZH8Nt92CDhPU/yqBLH3lBS7yVJUeyzY=";
+  };
+
+  nativeBuildInputs = [
+    pkgconf
+    pkg-config
+    wayland-scanner
+  ];
+
+  buildInputs = [
+    systemd
+    libbsd
+    wayland
+    wayland-protocols
+  ];
+
+  makeFlags = [ "WAYLAND=1" ];
+
+  installFlags = [ "PREFIX=$(out)" ];
+
+  meta = {
+    description = "Utility to prevent the system from entering an idle state";
+    homepage = "https://github.com/electrickite/caffeinated";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ lelgenio ];
+  };
+}