sway: allow setting both internal and external monitors

pkgs/lumactl.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  systemd,
+  libxkbcommon,
+  wayland,
+  wayland-scanner,
+  libffi,
+  wmctl,
+  makeWrapper,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "lumactl";
+  version = "0.1.0";
+
+  src = fetchFromGitHub {
+    owner = "danyspin97";
+    repo = pname;
+    rev = "89e273e25afe545e3bcaf282b84a63e3c34117de";
+    hash = "sha256-PQucBe3xPjjzuiaukdf2f/CvTqbGm0wJMbdpgd2ubnU=";
+  };
+
+  cargoHash = "sha256-RvC8wDCY22dBrUcl6VjrwMHwTTSSoBzLwnghAOAUoYU=";
+
+  nativeBuildInputs = [
+    pkg-config
+    wayland-scanner
+    makeWrapper
+  ];
+  buildInputs = [
+    systemd
+    libxkbcommon
+    wayland
+    libffi
+    wmctl
+  ];
+
+  postFixup = ''
+    wrapProgram $out/bin/lumactl \
+      --prefix PATH : ${lib.makeBinPath [ wmctl ]}
+  '';
+
+  meta = with lib; {
+    description = "CLI utility for controlling display brightness on Linux";
+    homepage = "https://github.com/danyspin97/lumactl";
+    license = licenses.gpl3Plus;
+    mainProgram = "lumactl";
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ lelgenio ];
+  };
+}